Fresh start: replace with naxIO/netfox-cs-sample foundation

Complete replacement of the tactical-shooter project with the
netfox-cs-sample (MIT) — a CS 1.6 inspired multiplayer FPS built
with Godot 4 and netfox.

## What's new
- Full CS-style gameplay: teams (T/CT), rounds, economy, buy menu
- 6 weapons: Knife, Glock, USP, AK-47, M4A1, AWP
- Bomb plant/defuse with 2 bombsites
- Flashbang & smoke grenades
- Proper netfox rollback netcode at 64 tick
- Network popup UI for host/join
- HUD, crosshair, round timer, scoreboard
- All netfox singletons registered as autoloads (works in exported builds)

## Architecture
- Listen-server (host from client, no dedicated server binary)
- Multiplayer-fps game lives at examples/multiplayer-fps/
- Netfox addons registered as autoloads for exported build compat
- Godot 4.7 with Forward+ renderer

## Removed
- Old headless-server architecture (client_main, server_main, player.gd, etc.)
- Custom netfox bootstrap with ENet fallback
- Old ChaffGames FPS template (2,420 lines, 844 KB)
- SimulationServer GDExtension stub
- Godot-jolt physics (netfox sample uses default Godot physics)
- Duplicate weapon_data.gd, anti_cheat.gd, round_manager.gd, etc.
- Server browser API Python venv (87 MB)
- test_range map and modular assets

## Preserved
- Git history
- Server config at config/default_server_config.cfg
- Windows export preset
- Build directory (gitignored)

Co-authored-by: naxIO <naxIO@users.noreply.github.com>

addons/vest/mocks/vest-mock-defs.gd

@@ -0,0 +1,68 @@
+extends Object
+class_name VestMockDefs
+
+## Grouping class for mock definition primitives.
+##
+## See [VestMockDefs.Answer][br]
+## See [VestMockDefs.Call][br]
+
+## Mock answer definition
+##
+## Each answer manages a mock method. When this method is called, instead of
+## running the underlying code, the answer provides a response.
+class Answer:
+	## The method this instance provides the answers for
+	var expected_method: Callable
+
+	## The expected arguments for providing the answers.
+	## [br][br]
+	## May be empty, in which case any and all parameters are accepted.
+	var expected_args: Array = []
+
+	var _answer_value: Variant
+	var _answer_method: Callable
+
+	func _get_specificity() -> int:
+		return expected_args.size()
+
+	func _is_answering(method: Callable, args: Array) -> bool:
+		if method != expected_method:
+			return false
+		if method.get_object() != expected_method.get_object():
+			return false
+		if expected_args.is_empty():
+			return true
+		if args.size() != expected_args.size():
+			return false
+		if args == expected_args:
+			return true
+
+		# Do a lenient check, so users don't trip on unexpected diffs, like
+		# [2, 4] != [2., 4.]
+		var lenient_actual := args.map(func(it): return _map_lenient(it))
+		var lenient_expected := expected_args.map(func(it): return _map_lenient(it))
+		if lenient_actual == lenient_expected:
+			return true
+		return false
+
+	func _get_answer(args: Array) -> Variant:
+		if _answer_method:
+			return _answer_method.call(args)
+		else:
+			return _answer_value
+
+	func _map_lenient(value: Variant) -> String:
+		if typeof(value) == TYPE_INT or typeof(value) == TYPE_FLOAT:
+			return "%.8f" % [value]
+		return str(value)
+
+	func _to_string() -> String:
+		return "Answer { %s.%s(%s) }" % [expected_method.get_object(), expected_method.get_method(), expected_args]
+
+## A recorded method call
+class Call:
+	## The method that was called
+	var method: Callable
+
+	## The arguments used for calling the method
+	var args: Array = []

addons/vest/mocks/vest-mock-defs.gd.uid

@@ -0,0 +1 @@
+uid://ct7m62cddavyk

addons/vest/mocks/vest-mock-dummy.gd

@@ -0,0 +1,3 @@
+extends Object
+
+# Dummy class to serve as a base for mocks

addons/vest/mocks/vest-mock-dummy.gd.uid

@@ -0,0 +1 @@
+uid://crbyd7o5c3qvh

addons/vest/mocks/vest-mock-generator.gd

@@ -0,0 +1,48 @@
+extends RefCounted
+class_name VestMockGenerator
+
+## Generates mocks for existing scripts
+##
+## @tutorial(Mocks): https://foxssake.github.io/vest/latest/user-guide/mocks/
+
+# TODO: Support getters and setters?
+
+## Generate a mocked version of a script
+func generate_mock_script(script: Script) -> Script:
+	var dummy_script := preload("res://addons/vest/mocks/vest-mock-dummy.gd") as Script
+	var mock_script := dummy_script.duplicate() as Script
+	mock_script.source_code = generate_mock_source(script)
+	mock_script.reload()
+
+	return mock_script
+
+## Generate the source code for mocking a script
+func generate_mock_source(script: Script) -> String:
+	var mock_source := PackedStringArray()
+
+	mock_source.append("extends \"%s\"\n\n" % [script.resource_path])
+	mock_source.append("var __vest_mock_handler: VestMockHandler\n\n")
+
+	for method in script.get_script_method_list():
+		var method_name := method["name"] as String
+		var method_args = method["args"]
+
+		if method_name.begins_with("@"):
+			# Getter or setter, don't generate as method
+			continue
+
+		var arg_defs := []
+
+		for arg in method_args:
+			var arg_name = arg["name"]
+			arg_defs.append(arg_name)
+
+		var arg_def_string := ", ".join(arg_defs)
+
+		mock_source.append(
+			("func %s(%s):\n" +
+			"\treturn __vest_mock_handler._handle(self.%s, [%s])\n\n") %
+			[method_name, arg_def_string, method_name, arg_def_string]
+		)
+
+	return "".join(mock_source)

addons/vest/mocks/vest-mock-generator.gd.uid

@@ -0,0 +1 @@
+uid://cawk4xgh75woy

addons/vest/mocks/vest-mock-handler.gd

@@ -0,0 +1,42 @@
+extends RefCounted
+class_name VestMockHandler
+
+## Manages mock instances
+
+var _answers: Array[VestMockDefs.Answer] = []
+var _calls: Array[VestMockDefs.Call] = []
+var _unhandled_calls: Array[VestMockDefs.Call] = []
+
+## Take over a mock instance, recording its calls and providing its answers
+func take_over(what: Object):
+	what.__vest_mock_handler = self
+
+## Register an answer
+func add_answer(answer: VestMockDefs.Answer):
+	_answers.append(answer)
+
+## Get all recorded mock calls
+func get_calls() -> Array[VestMockDefs.Call]:
+	return _calls
+
+## Get all recorded mock calls to which there were no registered answers
+func get_unhandled_calls() -> Array[VestMockDefs.Call]:
+	return _unhandled_calls
+
+func _handle(method: Callable, args: Array):
+	var call_data := VestMockDefs.Call.new()
+	call_data.method = method
+	call_data.args = args
+
+	var possible_answers = _answers\
+		.filter(func(it): return it._is_answering(method, args))
+	possible_answers.sort_custom(func(a, b): return a._get_specificity() > b._get_specificity())
+
+	if possible_answers.is_empty():
+		_unhandled_calls.append(call_data)
+		return
+
+	var answer := possible_answers.front() as VestMockDefs.Answer
+	_calls.append(call_data)
+
+	return answer._get_answer(args)

addons/vest/mocks/vest-mock-handler.gd.uid

@@ -0,0 +1 @@
+uid://0yq06hbkdt46