shawn
e7299b17e9
Stack installed: - netfox v1.35.3 (core + extras + noray + internals) - godot-jolt v0.16.0-stable Architecture: - Server: ENet transport (works headless, no netfox deps) - Client/Editor: netfox rollback (RollbackSynchronizer, TickInterpolator) New/modified: - docs/migration-netfox-plan.md — migration architecture - scripts/network/network_manager.gd — netfox-aware ENet fallback - scripts/network/player.gd — clean base player - client/characters/player_netfox.gd — rollback player w/ WeaponManager - client/characters/input/player_net_input.gd — BaseNetInput subclass - client/characters/character/fps_character_controller.gd — netfox input feed - client/weapons/ — weapon data, registry, TacticalWeaponHitscan, WeaponManager - client/scripts/round_replicator.gd — client-side round state bridge - server/scripts/round_manager.gd — improved state machine - server/scripts/plugin_api/plugin_manager.gd — refined plugin system - config: enemy_tag, ally_tag for meatball targeting Removed: old C++ SimulationServer GDExtension (replaced by netfox rollback)
45 lines
1.5 KiB
GDScript
45 lines
1.5 KiB
GDScript
extends Object
|
|
class_name _NetfoxEditorUtils
|
|
|
|
static func gather_properties(root: Node, callback_name: String, handler: Callable) -> Array[String]:
|
|
var result: Array[String] = []
|
|
|
|
var nodes: Array[Node] = root.find_children("*")
|
|
nodes.push_front(root)
|
|
for node in nodes:
|
|
if not node.has_method(callback_name):
|
|
continue
|
|
|
|
var readable_node_name := "\"%s\" (\"%s\")" % [node.name, root.get_path_to(node)]
|
|
if node.get(callback_name) == null:
|
|
result.push_back("Can't grab method \"%s\" from node %s! Is it a @tool?" % [callback_name, readable_node_name])
|
|
continue
|
|
|
|
var props = node.get(callback_name).call()
|
|
if not props is Array:
|
|
result.push_back("Node %s didn't return an array on calling \"%s\"" % [readable_node_name, callback_name])
|
|
continue
|
|
|
|
for prop in props:
|
|
if prop is String:
|
|
# Property is a string, meaning property path relative to node
|
|
handler.call(node, prop)
|
|
elif prop is Array and prop.size() >= 2:
|
|
# Property is a node-property tuple
|
|
var prop_node: Node = null
|
|
|
|
# Node can be a String, NodePath, or an actual Node
|
|
if prop[0] is String or prop[0] is NodePath:
|
|
prop_node = node.get_node(prop[0])
|
|
elif prop[0] is Node:
|
|
prop_node = prop[0]
|
|
else:
|
|
result.push_back("Node %s specified invalid node in \"%s\": %s" % [readable_node_name, callback_name, prop])
|
|
continue
|
|
|
|
handler.call(prop_node, prop[1])
|
|
else:
|
|
result.push_back("Node %s specified invalid property in \"%s\": %s" % [readable_node_name, callback_name, prop])
|
|
|
|
return result
|