Fresh start: replace with naxIO/netfox-cs-sample foundation

Complete replacement of the tactical-shooter project with the
netfox-cs-sample (MIT) — a CS 1.6 inspired multiplayer FPS built
with Godot 4 and netfox.

## What's new
- Full CS-style gameplay: teams (T/CT), rounds, economy, buy menu
- 6 weapons: Knife, Glock, USP, AK-47, M4A1, AWP
- Bomb plant/defuse with 2 bombsites
- Flashbang & smoke grenades
- Proper netfox rollback netcode at 64 tick
- Network popup UI for host/join
- HUD, crosshair, round timer, scoreboard
- All netfox singletons registered as autoloads (works in exported builds)

## Architecture
- Listen-server (host from client, no dedicated server binary)
- Multiplayer-fps game lives at examples/multiplayer-fps/
- Netfox addons registered as autoloads for exported build compat
- Godot 4.7 with Forward+ renderer

## Removed
- Old headless-server architecture (client_main, server_main, player.gd, etc.)
- Custom netfox bootstrap with ENet fallback
- Old ChaffGames FPS template (2,420 lines, 844 KB)
- SimulationServer GDExtension stub
- Godot-jolt physics (netfox sample uses default Godot physics)
- Duplicate weapon_data.gd, anti_cheat.gd, round_manager.gd, etc.
- Server browser API Python venv (87 MB)
- test_range map and modular assets

## Preserved
- Git history
- Server config at config/default_server_config.cfg
- Windows export preset
- Build directory (gitignored)

Co-authored-by: naxIO <naxIO@users.noreply.github.com>

test/netfox/servers/network-identity-server.perf.gd

@@ -0,0 +1,66 @@
+extends VestTest
+
+func get_suite_name() -> String:
+	return "NetworkIdentityServer"
+
+var command_server: _NetworkCommandServer
+var identity_server: _NetworkIdentityServer
+
+func before_case(__):
+	# Makes sure local peer is 1, otherwise identifiers get random local IDs
+	Vest.get_tree().root.multiplayer.multiplayer_peer = OfflineMultiplayerPeer.new()
+	
+	command_server = _NetworkCommandServer.new()
+	identity_server = _NetworkIdentityServer.new(command_server)
+
+	Vest.get_tree().root.add_child.call_deferred(command_server)
+	Vest.get_tree().root.add_child.call_deferred(identity_server)
+
+	await command_server.ready
+	await identity_server.ready
+
+func after_case(__):
+	identity_server.queue_free()
+	command_server.queue_free()
+
+func suite() -> void:
+	define("resolve_reference()", func():
+		# 6.04us/7.08us, 26.75us/32.29us, 211.05us/240.66us, 4.55ms/4.35ms
+		# ??/3.69us, ??/3.74us, ??/3.81us, ??/3.99us
+		# 2.73us/3.63us, 2.73us/3.72us, 2.68us/3.68us, 2.91us/3.95us
+		for case in [[16, 512], [128, 512], [1024, 512], [16384, 512]]:
+			var count := case[0] as int
+			var batch := case[1] as int
+
+			# Run benchmarks
+			test("resolve %d nodes" % count, func():
+				# Setup nodes
+				var nodes := [] as Array[Node]
+				for i in count:
+					var node := Node.new()
+					node.name = "Node %d" % i
+					nodes.append(node)
+					Vest.get_tree().root.add_child.call_deferred(node)
+
+				# Wait for nodes to be in tree and register
+				for node in nodes:
+					await node.ready
+					identity_server.register_node(node)
+
+				benchmark("resolve by ID", func(__):
+					var id := (randi() % count) as int
+					var reference := _NetworkIdentityReference.of_id(id)
+					identity_server._resolve_reference(1, reference, false)
+				).with_batch_size(batch).with_duration(1.).run()
+
+				benchmark("resolve by name", func(__):
+					var id := (randi() % count) as int
+					var reference := _NetworkIdentityReference.of_full_name("/root/Node %d" % id)
+					identity_server._resolve_reference(1, reference, false)
+				).with_batch_size(batch).with_duration(1.).run()
+
+				# Free nodes
+				for node in nodes:
+					node.queue_free()
+			)
+	)