Fresh start: replace with naxIO/netfox-cs-sample foundation

Complete replacement of the tactical-shooter project with the
netfox-cs-sample (MIT) — a CS 1.6 inspired multiplayer FPS built
with Godot 4 and netfox.

## What's new
- Full CS-style gameplay: teams (T/CT), rounds, economy, buy menu
- 6 weapons: Knife, Glock, USP, AK-47, M4A1, AWP
- Bomb plant/defuse with 2 bombsites
- Flashbang & smoke grenades
- Proper netfox rollback netcode at 64 tick
- Network popup UI for host/join
- HUD, crosshair, round timer, scoreboard
- All netfox singletons registered as autoloads (works in exported builds)

## Architecture
- Listen-server (host from client, no dedicated server binary)
- Multiplayer-fps game lives at examples/multiplayer-fps/
- Netfox addons registered as autoloads for exported build compat
- Godot 4.7 with Forward+ renderer

## Removed
- Old headless-server architecture (client_main, server_main, player.gd, etc.)
- Custom netfox bootstrap with ENet fallback
- Old ChaffGames FPS template (2,420 lines, 844 KB)
- SimulationServer GDExtension stub
- Godot-jolt physics (netfox sample uses default Godot physics)
- Duplicate weapon_data.gd, anti_cheat.gd, round_manager.gd, etc.
- Server browser API Python venv (87 MB)
- test_range map and modular assets

## Preserved
- Git history
- Server config at config/default_server_config.cfg
- Windows export preset
- Build directory (gitignored)

Co-authored-by: naxIO <naxIO@users.noreply.github.com>

examples/input-gathering/scripts/input-gathering.gd

@@ -0,0 +1,5 @@
+extends Object
+class_name ExampleInputGathering
+
+const Player := preload("res://examples/input-gathering/scripts/player.gd")
+const PlayerInput := preload("res://examples/input-gathering/scripts/player-input.gd")

examples/input-gathering/scripts/input-gathering.gd.uid

@@ -0,0 +1 @@
+uid://clxsr5e8urv2w

examples/input-gathering/scripts/player-input.gd

@@ -0,0 +1,40 @@
+extends BaseNetInput
+
+var movement: Vector3 = Vector3.ZERO
+var is_jumping: bool = false
+
+var _movement_buffer: Vector3 = Vector3.ZERO
+var _movement_samples: int = 0
+
+var _is_jumping_buffer: bool = false
+
+func _ready():
+	super()
+	NetworkTime.after_tick.connect(func(_dt, _t): _gather_always())
+
+func _process(_dt: float) -> void:
+	_movement_buffer += Vector3(
+		Input.get_axis("move_west", "move_east"),
+		Input.get_action_strength("move_jump"),
+		Input.get_axis("move_north", "move_south")
+	)
+	_movement_samples += 1
+
+	if Input.is_action_just_pressed("move_jump"):
+		_is_jumping_buffer = true
+
+func _gather() -> void:
+	# Average movement samples
+	if _movement_samples > 0:
+		movement = _movement_buffer / _movement_samples
+	else:
+		movement = Vector3.ZERO
+
+	# Reset buffer
+	_movement_buffer = Vector3.ZERO
+	_movement_samples = 0
+
+func _gather_always():
+	# Jumping
+	is_jumping = _is_jumping_buffer
+	_is_jumping_buffer = false

examples/input-gathering/scripts/player-input.gd.uid

@@ -0,0 +1 @@
+uid://bdc2cjgbgh4iw

examples/input-gathering/scripts/player-spawner.gd

@@ -0,0 +1,57 @@
+extends Node
+
+@export var player_scene: PackedScene
+@export var spawn_root: Node
+
+var avatars: Dictionary = {}
+
+func _ready():
+	NetworkEvents.on_client_start.connect(_handle_connected)
+	NetworkEvents.on_server_start.connect(_handle_host)
+	NetworkEvents.on_peer_join.connect(_handle_new_peer)
+	NetworkEvents.on_peer_leave.connect(_handle_leave)
+	NetworkEvents.on_client_stop.connect(_handle_stop)
+	NetworkEvents.on_server_stop.connect(_handle_stop)
+
+func _handle_connected(id: int):
+	# Spawn an avatar for us
+	_spawn(id)
+
+func _handle_host():
+	# Spawn own avatar on host machine
+	_spawn(1)
+
+func _handle_new_peer(id: int):
+	# Spawn an avatar for new player
+	_spawn(id)
+
+func _handle_leave(id: int):
+	if not avatars.has(id):
+		return
+	
+	var avatar = avatars[id] as Node
+	avatar.queue_free()
+	avatars.erase(id)
+
+func _handle_stop():
+	# Remove all avatars on game end
+	for avatar in avatars.values():
+		avatar.queue_free()
+	avatars.clear()
+
+func _spawn(id: int):
+	var avatar = player_scene.instantiate() as Node
+	avatars[id] = avatar
+	avatar.name += " #%d" % id
+	spawn_root.add_child(avatar)
+	
+	# Avatar is always owned by server
+	avatar.set_multiplayer_authority(1)
+
+	print("Spawned avatar %s at %s" % [avatar.name, multiplayer.get_unique_id()])
+	
+	# Avatar's input object is owned by player
+	var input = avatar.find_child("Input")
+	if input != null:
+		input.set_multiplayer_authority(id)
+		print("Set input(%s) ownership to %s" % [input.name, id])

examples/input-gathering/scripts/player-spawner.gd.uid

@@ -0,0 +1 @@
+uid://bvtisxluxnf7h

examples/input-gathering/scripts/player.gd

@@ -0,0 +1,47 @@
+extends CharacterBody3D
+
+@export var speed = 5.0
+@export var jump_velocity: float = 4.5
+@export var input: ExampleInputGathering.PlayerInput
+
+# Get the gravity from the project settings to be synced with RigidBody nodes.
+var gravity = ProjectSettings.get_setting(&"physics/3d/default_gravity")
+
+func _ready():
+	position = Vector3(0, 4, 0)
+	
+	if input == null:
+		input = $Input
+
+func _rollback_tick(delta, _tick, _is_fresh):
+	_force_update_is_on_floor()
+
+	# Add gravity
+	if not is_on_floor():
+		velocity.y -= gravity * delta
+
+	# Movement
+	var input_dir = input.movement
+	var direction = (transform.basis * Vector3(input_dir.x, 0, input_dir.z)).normalized()
+	if direction:
+		velocity.x = direction.x * speed
+		velocity.z = direction.z * speed
+	else:
+		velocity.x = move_toward(velocity.x, 0, speed)
+		velocity.z = move_toward(velocity.z, 0, speed)
+
+	# Jump
+	if input.is_jumping and is_on_floor():
+		velocity.y = jump_velocity
+
+	# move_and_slide assumes physics delta
+	# multiplying velocity by NetworkTime.physics_factor compensates for it
+	velocity *= NetworkTime.physics_factor
+	move_and_slide()
+	velocity /= NetworkTime.physics_factor
+
+func _force_update_is_on_floor():
+	var old_velocity = velocity
+	velocity *= 0
+	move_and_slide()
+	velocity = old_velocity

examples/input-gathering/scripts/player.gd.uid

@@ -0,0 +1 @@
+uid://clnh0o1qcycge