Fresh start: replace with naxIO/netfox-cs-sample foundation

Complete replacement of the tactical-shooter project with the
netfox-cs-sample (MIT) — a CS 1.6 inspired multiplayer FPS built
with Godot 4 and netfox.

## What's new
- Full CS-style gameplay: teams (T/CT), rounds, economy, buy menu
- 6 weapons: Knife, Glock, USP, AK-47, M4A1, AWP
- Bomb plant/defuse with 2 bombsites
- Flashbang & smoke grenades
- Proper netfox rollback netcode at 64 tick
- Network popup UI for host/join
- HUD, crosshair, round timer, scoreboard
- All netfox singletons registered as autoloads (works in exported builds)

## Architecture
- Listen-server (host from client, no dedicated server binary)
- Multiplayer-fps game lives at examples/multiplayer-fps/
- Netfox addons registered as autoloads for exported build compat
- Godot 4.7 with Forward+ renderer

## Removed
- Old headless-server architecture (client_main, server_main, player.gd, etc.)
- Custom netfox bootstrap with ENet fallback
- Old ChaffGames FPS template (2,420 lines, 844 KB)
- SimulationServer GDExtension stub
- Godot-jolt physics (netfox sample uses default Godot physics)
- Duplicate weapon_data.gd, anti_cheat.gd, round_manager.gd, etc.
- Server browser API Python venv (87 MB)
- test_range map and modular assets

## Preserved
- Git history
- Server config at config/default_server_config.cfg
- Windows export preset
- Build directory (gitignored)

Co-authored-by: naxIO <naxIO@users.noreply.github.com>

examples/forest-brawl/scripts/brawler-crown.gd

@@ -0,0 +1,50 @@
+extends Node3D
+
+@export var offset: Vector3 = Vector3(0, 2.5, 0)
+@export var tween_time: float = 0.2
+
+var is_enabled: bool = true
+var target: BrawlerController
+
+func _ready():
+	# Start as hidden
+	scale = Vector3.ZERO
+	is_enabled = false
+	
+	# Start animation
+	$"brawler-crown/AnimationPlayer".play("crown_rotate")
+	
+	GameEvents.on_scores_updated.connect(_handle_scores)
+
+func _process(delta):
+	if not target:
+		is_enabled = false
+	else:
+		var target_pos = target.global_position + offset
+		var dst = global_position.distance_squared_to(target_pos)
+		global_position = global_position.move_toward(target_pos, dst / tween_time * delta)
+		
+	scale = scale.move_toward(Vector3.ONE if is_enabled else Vector3.ZERO, delta / tween_time)
+	visible = scale.length_squared() > 0.05
+
+func _handle_scores(scores: Dictionary):
+	is_enabled = false
+
+	# No crown in single player
+	if scores.size() == 1:
+		return
+
+	var max_score = scores.values().max()
+	var max_players = scores.keys().filter(func(p): return scores[p] == max_score)
+	
+	# Multiple players share the crown
+	if max_players.size() > 1:
+		return
+	
+	var player_id = max_players[0]
+	var player = get_tree().get_nodes_in_group("Brawlers")\
+		.filter(func(it): return it.player_id == player_id)\
+		.pop_back()
+	
+	target = player
+	is_enabled = true