Fresh start: replace with naxIO/netfox-cs-sample foundation

Complete replacement of the tactical-shooter project with the
netfox-cs-sample (MIT) — a CS 1.6 inspired multiplayer FPS built
with Godot 4 and netfox.

## What's new
- Full CS-style gameplay: teams (T/CT), rounds, economy, buy menu
- 6 weapons: Knife, Glock, USP, AK-47, M4A1, AWP
- Bomb plant/defuse with 2 bombsites
- Flashbang & smoke grenades
- Proper netfox rollback netcode at 64 tick
- Network popup UI for host/join
- HUD, crosshair, round timer, scoreboard
- All netfox singletons registered as autoloads (works in exported builds)

## Architecture
- Listen-server (host from client, no dedicated server binary)
- Multiplayer-fps game lives at examples/multiplayer-fps/
- Netfox addons registered as autoloads for exported build compat
- Godot 4.7 with Forward+ renderer

## Removed
- Old headless-server architecture (client_main, server_main, player.gd, etc.)
- Custom netfox bootstrap with ENet fallback
- Old ChaffGames FPS template (2,420 lines, 844 KB)
- SimulationServer GDExtension stub
- Godot-jolt physics (netfox sample uses default Godot physics)
- Duplicate weapon_data.gd, anti_cheat.gd, round_manager.gd, etc.
- Server browser API Python venv (87 MB)
- test_range map and modular assets

## Preserved
- Git history
- Server config at config/default_server_config.cfg
- Windows export preset
- Build directory (gitignored)

Co-authored-by: naxIO <naxIO@users.noreply.github.com>

examples/forest-brawl/scripts/bomb-projectile.gd

@@ -0,0 +1,59 @@
+extends ShapeCast3D
+class_name BombProjectile
+
+@export var speed: float = 12.0
+@export var strength: float = 2.0
+@export var effect: PackedScene
+@export var distance: float = 128.0
+
+var distance_left: float
+var fired_by: Node
+var is_first_tick: bool = true
+
+func _ready():
+	NetworkTime.on_tick.connect(_tick)
+	distance_left = distance
+
+func _tick(delta, _t):
+	var dst = speed * delta
+	var motion = transform.basis.z * dst
+	target_position = Vector3.FORWARD * dst
+	distance_left -= dst
+
+	if distance_left < 0:
+		queue_free()
+	
+	# Check if we've hit anyone
+	force_shapecast_update()
+	
+	# Find the closest point of contact
+	var space := get_world_3d().direct_space_state
+	var query := PhysicsShapeQueryParameters3D.new()
+	query.motion = motion
+	query.shape = shape
+	query.transform = global_transform
+	
+	var hit_interval := space.cast_motion(query)
+	if hit_interval[0] != 1.0 or hit_interval[1] != 1.0 and not is_first_tick:
+		# Move to collision
+		position += motion * hit_interval[1]
+		_explode()
+	else:
+		position += motion
+
+	# Skip collisions for a single tick, no more
+	is_first_tick = false
+
+func _explode():
+	queue_free()
+	NetworkTime.on_tick.disconnect(_tick)
+	
+	if effect:
+		var spawn = effect.instantiate() as Node3D
+		get_tree().root.add_child(spawn)
+		spawn.global_position = global_position
+		spawn.fired_by = fired_by
+		spawn.set_multiplayer_authority(get_multiplayer_authority())
+		
+		if spawn is CPUParticles3D:
+			(spawn as CPUParticles3D).emitting = true