Fresh start: replace with naxIO/netfox-cs-sample foundation
Complete replacement of the tactical-shooter project with the netfox-cs-sample (MIT) — a CS 1.6 inspired multiplayer FPS built with Godot 4 and netfox. ## What's new - Full CS-style gameplay: teams (T/CT), rounds, economy, buy menu - 6 weapons: Knife, Glock, USP, AK-47, M4A1, AWP - Bomb plant/defuse with 2 bombsites - Flashbang & smoke grenades - Proper netfox rollback netcode at 64 tick - Network popup UI for host/join - HUD, crosshair, round timer, scoreboard - All netfox singletons registered as autoloads (works in exported builds) ## Architecture - Listen-server (host from client, no dedicated server binary) - Multiplayer-fps game lives at examples/multiplayer-fps/ - Netfox addons registered as autoloads for exported build compat - Godot 4.7 with Forward+ renderer ## Removed - Old headless-server architecture (client_main, server_main, player.gd, etc.) - Custom netfox bootstrap with ENet fallback - Old ChaffGames FPS template (2,420 lines, 844 KB) - SimulationServer GDExtension stub - Godot-jolt physics (netfox sample uses default Godot physics) - Duplicate weapon_data.gd, anti_cheat.gd, round_manager.gd, etc. - Server browser API Python venv (87 MB) - test_range map and modular assets ## Preserved - Git history - Server config at config/default_server_config.cfg - Windows export preset - Build directory (gitignored) Co-authored-by: naxIO <naxIO@users.noreply.github.com>
This commit is contained in:
@@ -0,0 +1,37 @@
|
||||
extends RefCounted
|
||||
class_name _BaseSnapshotSerializer
|
||||
|
||||
var _identity_server: _NetworkIdentityServer
|
||||
var _schemas: _NetworkSchema
|
||||
|
||||
static var _default_filter := func(subject: Object): return true
|
||||
static var _logger := NetfoxLogger._for_netfox("DenseSnapshotSerializer")
|
||||
|
||||
func _init(p_schemas: _NetworkSchema, p_identity_server: _NetworkIdentityServer = null):
|
||||
assert(p_schemas != null, "Missing schemas!")
|
||||
# Intentionally storing reference, so it can be modified from the outside
|
||||
# e.g. RollbackSynchronizerServer adds a property
|
||||
_schemas = p_schemas
|
||||
_identity_server = p_identity_server
|
||||
|
||||
func _write_property(node: Node, property: NodePath, value: Variant, buffer: StreamPeerBuffer) -> void:
|
||||
_schemas.encode(node, property, value, buffer)
|
||||
|
||||
func _read_property(node: Node, property: NodePath, buffer: StreamPeerBuffer) -> Variant:
|
||||
return _schemas.decode(node, property, buffer)
|
||||
|
||||
func _write_identifier(subject: Object, peer: int, buffer: StreamPeerBuffer) -> Error:
|
||||
var netref := NetworkSchemas._netref()
|
||||
var identifier := _get_identity_server()._get_identifier_of(subject)
|
||||
if not identifier:
|
||||
_logger.error("Can't synchronize %s, identifier missing!", [subject])
|
||||
return ERR_DOES_NOT_EXIST
|
||||
|
||||
var idref := identifier.reference_for(peer)
|
||||
netref.encode(idref, buffer)
|
||||
return OK
|
||||
|
||||
func _get_identity_server() -> _NetworkIdentityServer:
|
||||
if not _identity_server:
|
||||
_identity_server = NetworkIdentityServer
|
||||
return _identity_server
|
||||
@@ -0,0 +1 @@
|
||||
uid://b8mn7i6dnt0bu
|
||||
@@ -0,0 +1,87 @@
|
||||
extends _BaseSnapshotSerializer
|
||||
class_name _DenseSnapshotSerializer
|
||||
|
||||
static func _static_init():
|
||||
_logger = NetfoxLogger._for_netfox("DenseSnapshotSerializer")
|
||||
|
||||
func write_for(peer: int, snapshot: _Snapshot, properties: _PropertyPool, filter: Callable = _default_filter, buffer: StreamPeerBuffer = null) -> PackedByteArray:
|
||||
if buffer == null:
|
||||
buffer = StreamPeerBuffer.new()
|
||||
|
||||
var netref := NetworkSchemas._netref()
|
||||
var varuint := NetworkSchemas.varuint()
|
||||
|
||||
var node_buffer := StreamPeerBuffer.new()
|
||||
|
||||
var has_data := false
|
||||
|
||||
# Write tick
|
||||
buffer.put_u32(snapshot.tick)
|
||||
|
||||
# For each node
|
||||
for subject in properties.get_subjects():
|
||||
if not filter.call(subject): continue
|
||||
if not snapshot.is_auth(subject): continue
|
||||
|
||||
var node := subject as Node
|
||||
assert(node.is_multiplayer_authority(), "Trying to serialize state for non-owned node!")
|
||||
assert(snapshot.is_auth(node), "Trying to serialize non-auth state node!")
|
||||
|
||||
# Write identifier
|
||||
if _write_identifier(node, peer, buffer) != OK:
|
||||
continue
|
||||
|
||||
# Write properties as-is
|
||||
# First into a buffer, so we can start with the state size
|
||||
node_buffer.clear()
|
||||
for property in properties.get_properties_of(node):
|
||||
assert(snapshot.has_property(node, property), "Trying to serialize missing property %s on subject %s!" % [property, node])
|
||||
|
||||
var value := snapshot.get_property(node, property)
|
||||
_write_property(node, property, value, node_buffer)
|
||||
|
||||
# Indicate state size for the node
|
||||
varuint.encode(node_buffer.data_array.size(), buffer)
|
||||
|
||||
# Write node state
|
||||
buffer.put_data(node_buffer.data_array)
|
||||
|
||||
has_data = true
|
||||
|
||||
if has_data:
|
||||
return buffer.data_array
|
||||
else:
|
||||
return PackedByteArray()
|
||||
|
||||
func read_from(peer: int, properties: _PropertyPool, buffer: StreamPeerBuffer, is_auth: bool = true) -> _Snapshot:
|
||||
var netref := NetworkSchemas._netref()
|
||||
var varuint := NetworkSchemas.varuint()
|
||||
var node_buffer := StreamPeerBuffer.new()
|
||||
|
||||
# Read tick
|
||||
var tick := buffer.get_u32()
|
||||
var snapshot := _Snapshot.new(tick)
|
||||
|
||||
while buffer.get_available_bytes() > 0:
|
||||
# Read identity reference, data size, and data
|
||||
var idref := netref.decode(buffer) as _NetworkIdentityReference
|
||||
var node_data_size := varuint.decode(buffer) as int
|
||||
node_buffer.data_array = buffer.get_partial_data(node_data_size)[1]
|
||||
|
||||
# Resolve to identifier
|
||||
var identifier := _get_identity_server()._resolve_reference(peer, idref)
|
||||
if not identifier:
|
||||
# TODO(#563): Handle unknown IDs gracefully
|
||||
_logger.warning("Received unknown identity reference %s, skipping data", [idref])
|
||||
continue
|
||||
var node := identifier.get_subject() as Node
|
||||
|
||||
# Read properties
|
||||
for property in properties.get_properties_of(node):
|
||||
if node_buffer.get_available_bytes() == 0: break
|
||||
|
||||
var value := _read_property(node, property, node_buffer)
|
||||
snapshot.set_property(node, property, value)
|
||||
snapshot.set_auth(node, is_auth)
|
||||
|
||||
return snapshot
|
||||
@@ -0,0 +1 @@
|
||||
uid://k37sxuptebt3
|
||||
@@ -0,0 +1 @@
|
||||
uid://bf67e0hnmp70h
|
||||
@@ -0,0 +1,40 @@
|
||||
extends _BaseSnapshotSerializer
|
||||
class_name _RedundantSnapshotSerializer
|
||||
|
||||
var _dense_serializer: _DenseSnapshotSerializer
|
||||
|
||||
static func _static_init():
|
||||
_logger = NetfoxLogger._for_netfox("RedundantSnapshotSerializer")
|
||||
|
||||
func _init(p_schemas: _NetworkSchema, p_identity_server: _NetworkIdentityServer = null):
|
||||
super(p_schemas)
|
||||
_dense_serializer = _DenseSnapshotSerializer.new(_schemas, p_identity_server)
|
||||
|
||||
func write_for(peer: int, snapshots: Array[_Snapshot], properties: _PropertyPool, buffer: StreamPeerBuffer = null) -> PackedByteArray:
|
||||
var varuint := NetworkSchemas.varuint()
|
||||
|
||||
if buffer == null:
|
||||
buffer = StreamPeerBuffer.new()
|
||||
|
||||
# TODO(#560): How about encoding the first snapshot as-is, and then the rest as diffs
|
||||
for snapshot in snapshots:
|
||||
var serialized := _dense_serializer.write_for(peer, snapshot, properties)
|
||||
|
||||
# Write size and snapshot
|
||||
varuint.encode(serialized.size(), buffer)
|
||||
buffer.put_data(serialized)
|
||||
|
||||
return buffer.data_array
|
||||
|
||||
func read_from(peer: int, properties: _PropertyPool, buffer: StreamPeerBuffer, is_auth: bool = true) -> Array[_Snapshot]:
|
||||
var varuint := NetworkSchemas.varuint()
|
||||
|
||||
var snapshots := [] as Array[_Snapshot]
|
||||
while buffer.get_available_bytes() > 0:
|
||||
var snapshot_size := varuint.decode(buffer)
|
||||
var snapshot_buffer := StreamPeerBuffer.new()
|
||||
snapshot_buffer.data_array = buffer.get_partial_data(snapshot_size)[1]
|
||||
|
||||
var snapshot := _dense_serializer.read_from(peer, properties, snapshot_buffer, is_auth)
|
||||
snapshots.append(snapshot)
|
||||
return snapshots
|
||||
@@ -0,0 +1 @@
|
||||
uid://ch0p4f4nuy1c
|
||||
@@ -0,0 +1,92 @@
|
||||
extends _BaseSnapshotSerializer
|
||||
class_name _SparseSnapshotSerializer
|
||||
|
||||
static func _static_init():
|
||||
_logger = NetfoxLogger._for_netfox("SparseSnapshotSerializer")
|
||||
|
||||
func write_for(peer: int, snapshot: _Snapshot, properties: _PropertyPool, filter: Callable = _default_filter, buffer: StreamPeerBuffer = null) -> PackedByteArray:
|
||||
if buffer == null:
|
||||
buffer = StreamPeerBuffer.new()
|
||||
|
||||
var netref := NetworkSchemas._netref()
|
||||
var varuint := NetworkSchemas.varuint()
|
||||
var varbits := NetworkSchemas._varbits()
|
||||
|
||||
var node_buffer := StreamPeerBuffer.new()
|
||||
|
||||
var has_data := false
|
||||
|
||||
# Write ticks
|
||||
buffer.put_u32(snapshot.tick)
|
||||
|
||||
# For each node
|
||||
for subject in properties.get_subjects():
|
||||
if not filter.call(subject): continue
|
||||
if not snapshot.is_auth(subject): continue
|
||||
|
||||
var node := subject as Node
|
||||
assert(node.is_multiplayer_authority(), "Trying to serialize state for non-owned node!")
|
||||
assert(snapshot.is_auth(node), "Trying to serialize non-auth state node!")
|
||||
|
||||
# Write identifier
|
||||
if _write_identifier(node, peer, buffer) != OK:
|
||||
continue
|
||||
|
||||
node_buffer.clear()
|
||||
|
||||
var node_props := properties.get_properties_of(node)
|
||||
var changed_bits := _Bitset.new(node_props.size())
|
||||
|
||||
for i in node_props.size():
|
||||
var property := node_props[i]
|
||||
if not snapshot.has_property(node, property):
|
||||
continue
|
||||
|
||||
changed_bits.set_bit(i)
|
||||
var value := snapshot.get_property(node, property)
|
||||
_write_property(node, property, value, node_buffer)
|
||||
|
||||
varuint.encode(node_buffer.data_array.size(), buffer) # Node props len
|
||||
varbits.encode(changed_bits, buffer) # Changed prop bits
|
||||
buffer.put_data(node_buffer.data_array) # Changed props
|
||||
has_data = true
|
||||
|
||||
if has_data:
|
||||
return buffer.data_array
|
||||
else:
|
||||
# Return an empty buffer if we ended up not serializing anything
|
||||
return PackedByteArray()
|
||||
|
||||
func read_from(peer: int, properties: _PropertyPool, buffer: StreamPeerBuffer, is_auth: bool = true) -> _Snapshot:
|
||||
var netref := NetworkSchemas._netref()
|
||||
var varuint := NetworkSchemas.varuint()
|
||||
var varbits := NetworkSchemas._varbits()
|
||||
var node_buffer := StreamPeerBuffer.new()
|
||||
|
||||
# Grab ticks
|
||||
var tick := buffer.get_u32()
|
||||
var snapshot := _Snapshot.new(tick)
|
||||
|
||||
while buffer.get_available_bytes() > 0:
|
||||
# Read header, including identity reference
|
||||
var idref := netref.decode(buffer) as _NetworkIdentityReference
|
||||
var node_data_size := varuint.decode(buffer) as int
|
||||
var changed_bits := varbits.decode(buffer) as _Bitset
|
||||
node_buffer.data_array = buffer.get_partial_data(node_data_size)[1]
|
||||
|
||||
# Resolve to identifier
|
||||
var identifier := _get_identity_server()._resolve_reference(peer, idref)
|
||||
if not identifier:
|
||||
# TODO(#563): Handle unknown IDs gracefully
|
||||
_logger.warning("Received unknown identity reference %s, skipping data", [idref])
|
||||
break
|
||||
var node := identifier.get_subject() as Node
|
||||
|
||||
# Read changed properties
|
||||
var node_props := properties.get_properties_of(node)
|
||||
for idx in changed_bits.get_set_indices():
|
||||
var property := node_props[idx]
|
||||
var value := _read_property(node, property, node_buffer)
|
||||
snapshot.set_property(node, property, value)
|
||||
snapshot.set_auth(node, is_auth)
|
||||
return snapshot
|
||||
@@ -0,0 +1 @@
|
||||
uid://b01d03njlfhh1
|
||||
Reference in New Issue
Block a user